READ ME:

*This is a guide to explain what all is happening in the excel spreadsheet: “Testing Model\_Volunteer and Mandatory Selection.xlsx”*

# Hierarchy of Data:

**“Raw Event Data”**

*Volunteer and Mandatory List Order (Seniority)*

*Event Selection Results Data*

*System Analysis Data*

*Mandatory and Volunteer List Order*

*Mandatory List Order*

**“Event Selection\_Skipping All”**

**“Charts”**

**“Analysis”**

**“Event Selection\_Seniority”**

**“Event Selection\_Skipping Man”**

*Individual PEO Volunteer choices for each Event*

*PEO Staffing Needs for the 281 Special Events in 2022*

**“PEO Volunteer Sheet”**

**“Vol and Man List”**

**“Skipping Man List”**

**“Skipping All List”**

# Event data, and PEO volunteering.

“Raw Event Data”

* In sheet “Raw Event Data”, I have pasted in the PEO staffing needs for each event in 2022.
* After clearing out all null or 0 values, I was left with 281 events. Column D references the Event and It’s number in sequence. Column E is each event’s staffing need.
* I then transposed those staffing needs into cell F2. The cells F2:JZ2 will be referenced in future sheets.

### “PEO Volunteer Sheet”

* This sheet is the engine for volunteer data. In column A, I created rows for each PEO totaling 80. In range C2:JX3 I pasted the Event # and the PEO staffing need for that event.
* Each cell in Range D3:JX82 has a value of TRUE or FALSE. A TRUE value in cell D3 means that PEO 1 **volunteered** for Event 1.
* The values are determined by the formula =RANDBETWEEN().
* For the model to work, the values inside the volunteer range need to be static, which is why you don’t see a formula in them.
  + To test different volunteer rates, or test the same rate multiple times, take the formula in cell JZ3 [*=IF(RANDBETWEEN(0,100)<=$KA$3, TRUE, FALSE)*], and paste it into every cell in the volunteer range [D3:JX82].
  + Once each cell has the formula, go to cell KA3 and input your desired volunteer rate. (Use whole numbers to reflect percentages—20.00 = 20%.)
  + Cells KB3:KD3 are there to test if the outcome is accurate to the desired volunteer rate.
  + Once you have the desired outcome, copy all cells from the volunteer range [D3:JX82] and “paste special” -> “values”.

### “Vol and Man List”

* This sheet is where the raw volunteer data goes to get sorted for the Seniority Model.
* Column A is a helpful column with section labels and #’s to make sure I am not missing any data.
* Section 1 is from rows 1-82 and defined by black outlines. This section is to sort out which PEO’s volunteered for each event.
* Columns D1:JX1 are labels for each event number.
* To filter out and sort each volunteer I used the formula *[=SORT(FILTER('PEO Volunteer Sheet'!$A$3:$A$82, 'PEO Volunteer Sheet'!D$3:D$82 = TRUE), 1, 1)]*
  + This does 3 things:
    - References which values were true for Event #1 in the “PEO Volunteer Sheet” sheet.
    - Takes the corresponding PEO # from column A in that sheet
    - Sorts them based on seniority
* What we are left with is list of volunteers for that specific event in seniority order.
  + That is repeated for every single event.
* Section 2, starting at Row 83, is the same process but filters and sorts the data by FALSE values (did not volunteer).
  + This is sorted in Reverse Seniority, and repeated.
* Section 3, starting at Row 166, combines the lists using this formula [*=VSTACK(FILTER(D$2:D81, D$2:D$81 <>""), FILTER(D$84:D$165,D$84:D$165<>""))*]
  + This does 3 things:
    - Filters the entire range for volunteers for that event, excluding null values
    - Filters the mandatory range (non-volunteers), excluding null values
    - Combines them, putting the volunteers on top and the mandatory list just below
* We are left with an exact list of who should be picked in order.

# Seniority Model

### “Event Selection\_Seniority”

* This sheet is where selection actually happens.
* Column A is a list of PEO’s 1-80
* Column B is a COUNTIF() function that tally’s how many times the corresponding value in column A occurs. [*=COUNTIF($D$3:$JX$82,A3)*].
* Cell C1 is a reference cell for all of the Event data. It’s pulled from the “PEO Volunteer Sheet” sheet to ensure all systems have the same event data. The reference fills in the Range C1:JX2 total 281 Events and their staffing needs.
* The events are then filled in row 3 using this formula [*=INDEX('Vol and Man List'!D$167#,SEQUENCE(D$1))*]
  + This formula does 2 things
    - Pulls in the entire combined list from “Vol and Man List” [D$167#]
    - Lists them in sequence until the number of PEO’s needed is filled. (The sequence length is determined by cell D$1)
* This is repeated for every event column.
* Now all Events have been filled.
* Data is referenced in the “Analysis” sheet which I will touch on more later

# Skipping Mandatory Only Model

### “Skipping Man List”

* This sheet is where the raw non-volunteer data goes to get sorted for the Skipping Mandatory Only Model.
* Volunteer data is pulled from the “Vol and Man List” sheet as to reduce redundancy.
* Column A is a helpful column with section labels and #’s to make sure I am not missing any data.
* The Event data is pulled into cell C2 to keep consistency.
* Section 1 from rows 1-82 is outline in black. It is used to identify who was mandatorily selected for each event.
* Cell D3 uses this formula to identify is any PEO is being selected when they did not volunteer.
  + *=IFERROR(FILTER('Event Selection\_Skipping Man'!D$3:D$82, ISNUMBER(MATCH('Event Selection\_Skipping Man'!D$3:D$82, 'Vol and Man List'!D$84:D$164, 0))), "")*
    - This formula does a lot but in short:
      * Filters the actually selected PEOs in the “Event Selection\_Skipping Man” sheet for Event 1, by only those who were part of the mandatory list for Event 1 in the “Vol and Man list” sheet.
      * Retains their spot in order of selection. (The correct order is imprinted on the original picking list.
* This is repeated for every event column.
* Section 2 is rows 84-164. This section is to send the PEOs who were mandatorily selected to the bottom of the mandatory list.
* Range D85:D164 is the starting point showing Reverse seniority. (Starting from Square 1)
* Cell E85# is where the magic happens. This is where the list is reordered.
  + *=VSTACK(FILTER(D$85:D$164, ISERROR(MATCH(D$85:D$164, D$3#, 0))),D$3#)*
    - This formula does 2 things.
      * Filters out any PEO who was mandatorily selected for Event 1
      * Stacks that filtered list on top, and the list of PEOs who were selected [D3#] at the bottom.
* Now we are left with a new list of PEOs in the correct order. This is the “Wheel”.
* This is repeated for every event column.
* Section 3 is rows 165-248.
* Just like in the volunteer model, this section filters out a list of only the PEOs who did not volunteer, pulled from the “Vol and Man List” Sheet, and then order them using the adjusted Mandatory list we just made.
  + *=FILTER('Skipping Man List'!D$85:D$164, ISNUMBER(MATCH('Skipping Man List'!D$85:D$164, 'Vol and Man List'!D$84:D$165, 0)))*
* Section 4, rows 249-330, is bringing the volunteer and mandatory lists together.
* It stacks the volunteer list we used for the Seniority system with the mandatory list we just created using this formula:
  + *=VSTACK(FILTER('Vol and Man List'!D$2:D$81, 'Vol and Man List'!D$2:D$81 <>""), FILTER(D$168:D$247,D$168:D$247<>""))*
* This is repeated for all event columns.
* We are left with an exact list of who should be picked in order.

### “Event Selection\_Skipping Man”

* This sheet is where selection actually happens.
* Column A is a list of PEO’s 1-80
* Column B is a COUNTIF() function that tally’s how many times the corresponding value in column A occurs. [*=COUNTIF($D$3:$JX$82,A3)*].
* Cell C1 is a reference cell for all of the Event data. It’s pulled from the “PEO Volunteer Sheet” sheet to ensure all systems have the same event data. The reference fills in the Range C1:JX2 total 281 Events and their staffing needs.
* The events are then filled in row 3 using this formula
  + *=INDEX('Skipping Man List'!D$250#,SEQUENCE(D$1))*
    - This formula does 2 things.
      * Pulls in the entire combined list from “Skipping Man List” [D$250#]
      * Lists them in sequence until the number of PEO’s needed is filled. (The sequence length is determined by cell D$1)
* This is repeated for every event column.
* Now all Events have been filled.
* Data is referenced in the “Analysis” sheet which I will touch on more later.

# Skipping All Model

### “Skipping All List”

* As you can guess this is rinse and repeat.
* The biggest difference is that volunteer list, adjustment, and reselection is added alongside the Mandatory list, adjustment, and reselection.
* The volunteer list adjustments and formulas are from Rows 1 to 247
* The mandatory list adjustments and formulas are from Rows 332-578
* The combined list output is from rows 249-330
  + Sandwiched between volunteer and mandatory.
* We are left with an exact list of who should be picked and in what order.

### “Event Selection\_Skipping All”

* This is exactly the same as the “Event Selection\_Skipping Man” and “Event Selection\_Seniority” sheets.
* Data is referenced in the “Analysis” sheet which I will touch on more right now

# Analysis and Charts

### “Analysis”

* All the selection data is pulled to this sheet for analysis.
* Section 1 is the satisfaction scores from the Seniority System: Row 1 to 83
  + Column A is the PEOs in seniority order.
  + B1 is the title
  + B2:JV2 are the Event #s.
  + Each cell from B2:JV82 has a value of 1 or -1. This is their satisfaction with their selection status for the given event. The formula to get this is:
    - *=IFS(AND('PEO Volunteer Sheet'!D3=TRUE, ISNUMBER(MATCH('PEO Volunteer Sheet'!$A3, 'Event Selection\_Seniority'!D$3#, 0))),1, AND('PEO Volunteer Sheet'!D3=FALSE, ISNUMBER(MATCH('PEO Volunteer Sheet'!$A3, 'Event Selection\_Seniority'!D$3#, 0))),-1,AND('PEO Volunteer Sheet'!D3=TRUE, NOT(ISNUMBER(MATCH('PEO Volunteer Sheet'!$A3, 'Event Selection\_Seniority'!D$3#, 0)))),-1, AND('PEO Volunteer Sheet'!D3=FALSE, NOT(ISNUMBER(MATCH('PEO Volunteer Sheet'!$A3, 'Event Selection\_Seniority'!D$3#, 0)))),1)*
    - This is an IF statement with 4 potential options.
      * Volunteered and Selected : +1
      * Volunteer and Not-Selected: -1
      * Non-Volunteer and Selected: -1
      * Non-Volunteer and Not-Selected: +1
    - The formula compares the result from the “Event Selection\_Seniority” sheet to the volunteer election from the “PEO Volunteer Sheet”, then returns the result for which of the 4 options is TRUE.
  + All of the scores from that Row are then added together using the formula *=SUM(B3:JV3).*
    - This is the formula for the PEO in Row 3 which is PEO 1 (highest seniority).
  + All 80 PEOs receive a “Satisfaction Score” which is displayed in range JX3:JX82.
* Section 2 is the satisfaction scores from the Skipping Man System: Row 84 to 166
  + This is the exact same system, just referencing the relevant Skipping Mandatory Only data.
* Section 3 is the satisfaction scores from the Skipping All System: Row 167 to 249
  + This is the exact same system, just referencing the relevant Skipping All data.
* Section 4 is the comparison section/chart reference data
  + Satisfaction Scores
    - Seniority Satisfaction scores are referenced in Range C253:C332.
    - Skipping Mandatory Only Scores are referenced in E253:E332.
    - Skipping All Scores are referenced in G253:G332.
  + Average Satisfaction Scores for Top 40 and Bottom 40 PEOs
    - L251:N255
  + Total Events Selected
    - Seniority is referenced from the B column in the “Event Selection\_Seniority” sheet.
    - Skipping Mandatory Only is from the B column in the “Event Selection\_Skipping Man” Sheet
    - Skipping All data is from the B column in the “Event Selection\_Skipping All” sheet
  + Average Events Selected for Top 40 and Bottom 40 PEOs
    - U251:W255

### “Charts”

* There are 3 charts in this sheet.
  + Satisfaction Scores by Selection System
    - Pulled from the “Analysis” sheet. Ranges, C253:C332, E253:E332, G253:G332
  + Events Worked by PEOs in Seniority Order
    - Pulled from the “Analysis” sheet. Ranges, Q253:Q332, R253:R332, S253:S332
  + PEO Positions Needed per Event
    - Pulled from the “Raw Events Data” sheet. Ranges: E3:E283